blob: 9032070f7131fd8747d5385dda55d8a41dc153aa (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Nathan Loewen <loewen.nathan@gmail.com>
# Contributor: Christian Hesse <mail@eworm.de>
# Contributor: Alexey Vasiliev <robbinton@gmail.com>
pkgname=freerdp-git
pkgdesc='Free RDP client - git checkout'
pkgver=2.0.0.rc4.r1127.g2df3eb045
pkgrel=1
depends=('openssl' 'libxcursor' 'libcups' 'alsa-lib' 'libxext' 'libxdamage'
'ffmpeg' 'libxkbfile' 'libxinerama' 'libxv' 'openh264')
makedepends=('git' 'krb5' 'cmake' 'xorgproto')
arch=('i686' 'x86_64')
url="http://www.freerdp.com/"
license=('GPL')
provides=('freerdp')
conflicts=('freerdp')
source=('freerdp::git://github.com/FreeRDP/FreeRDP.git')
sha256sums=('SKIP')
pkgver() {
cd freerdp/
if GITTAG="$(git describe --abbrev=0 --tags 2>/dev/null)"; then
printf '%s.r%s.g%s' \
"$(sed -e "s/^${pkgname%%-git}//" -e 's/^[-_/a-zA-Z]\+//' -e 's/[-_+]/./g' <<< ${GITTAG})" \
"$(git rev-list --count ${GITTAG}..)" \
"$(git rev-parse --short HEAD)"
else
printf '0.r%s.g%s' \
"$(git rev-list --count master)" \
"$(git rev-parse --short HEAD)"
fi
}
build() {
cd freerdp/
cmake \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DWITH_PULSE=ON \
-DWITH_SERVER=ON \
-DWITH_OPENH264=ON \
-DWITH_CUPS=ON \
.
make
}
package() {
cd freerdp/
make DESTDIR="${pkgdir}/" install
}
|