blob: 6b5ed6aebce9707c3690faf61f03e763e91b21e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: Raphaël Doursenaud <rdoursenaud@free.fr>
pkgname=frescobaldi-git
pkgver=v2.18.1.r3.g6b4031a
pkgrel=1
pkgdesc="A LilyPond sheet music text editor."
arch=('any')
url="http://www.frescobaldi.org/"
license=('GPL')
depends=(
'hyphen'
'poppler'
'python>=3.2'
'python-ly'
'python-poppler-qt4'
'python-pyqt4>=4.8.3'
'qt4>=4.7'
'tango-icon-theme'
)
optdepends=(
'lilypond: Music engraving (recommended)'
# python-portmidi is currently a python2 package
# 'python-portmidi: MIDI playback (default engine)'
'python-pygame-hg: MIDI playback (alternate engine)'
'portmidi: MIDI playback (fallback engine)'
'hyphen-de: German hyphenation rules'
'hyphen-en: English hyphenation rules'
'hyphen-es: Spanish hyphenation rules'
'hyphen-fr: French hyphenation rules'
'hyphen-hu: Hungarian hyphenation rules'
'hyphen-it: Italian hyphenation rules'
'hyphen-nl: Dutch hyphenation rules'
'hyphen-ro: Romanian hyphenation rules'
)
conflicts=('frescobaldi')
provides=('frescobaldi')
source=("$pkgname"::'git://github.com/wbsoft/frescobaldi.git')
install=frescobaldi-git.install
md5sums=('SKIP')
_gitroot='https://github.com/wbsoft/frescobaldi.git'
_gitname='frescobaldi'
pkgver() {
cd "$srcdir/$pkgname"
git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/$pkgname"
# Provided by tango-icon-theme
rm -rf "frescobaldi_app/icons/Tango"
# Provided by hyphen-*
rm -rf "frescobaldi_app/hyphdicts"
}
package() {
cd "$srcdir/$pkgname"
python setup.py install --root="$pkgdir/" --optimize=1
}
# vim:set ts=2 sw=2 et:
|