blob: 81b8d9aad97a4e37e222e6540b70aabd267cdff4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Noam Lewis
#
# Binary package - downloads prebuilt binary from GitHub releases
pkgname=fresh-editor-bin
pkgver=0.2.23
pkgrel=1
pkgdesc="A lightweight, fast terminal-based text editor with LSP support and TypeScript plugins"
url="https://sinelaw.github.io/fresh/"
license=("GPL-2.0-only")
arch=('x86_64' 'aarch64')
source_x86_64=("fresh-editor-${pkgver}-x86_64.tar.xz::https://github.com/sinelaw/fresh/releases/download/v${pkgver}/fresh-editor-x86_64-unknown-linux-gnu.tar.xz"
"https://raw.githubusercontent.com/sinelaw/fresh/master/LICENSE")
source_aarch64=("fresh-editor-${pkgver}-aarch64.tar.xz::https://github.com/sinelaw/fresh/releases/download/v${pkgver}/fresh-editor-aarch64-unknown-linux-gnu.tar.xz"
"https://raw.githubusercontent.com/sinelaw/fresh/master/LICENSE")
sha256sums_x86_64=("50670e9210a4469b5ae4021202727f8d6a077edef58a89220fe6c8785c5d4392"
"SKIP")
sha256sums_aarch64=("353856e664e8cdb321bb0bfcec44b0cacf7491d1394fa7fd7da08ad8a66f24b4"
"SKIP")
depends=("gcc-libs" "glibc")
provides=("fresh-editor")
conflicts=("fresh-editor")
options=('!debug')
package() {
cd "fresh-editor-$CARCH-unknown-linux-gnu"
# Binary (installed alongside plugins, symlinked from /usr/bin)
install -Dm755 fresh "$pkgdir/usr/share/fresh-editor/fresh"
install -dm755 "$pkgdir/usr/bin"
ln -s "/usr/share/fresh-editor/fresh" "$pkgdir/usr/bin/fresh"
# Documentation
install -Dm644 README.md "$pkgdir/usr/share/doc/fresh-editor/README.md"
# License
install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
# Plugins
cp -r plugins "$pkgdir/usr/share/fresh-editor/"
# Desktop file
install -Dm644 fresh.desktop "$pkgdir/usr/share/applications/fresh.desktop"
# Hicolor icons
for icon in icons/*/apps/fresh.png; do
size=$(basename $(dirname $(dirname "$icon")))
install -Dm644 "$icon" "$pkgdir/usr/share/icons/hicolor/${size}/apps/fresh.png"
done
}
|