PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: Jan "heftig" Steffens <jan.steffens@gmail.com>
# Contributor: Allan McRae <allan@archlinux.org>
# Contributor: Brandon Niemczyk <maccorin@cfl.rr.com>

pkgname=frozen-bubble
pkgver=2.212
pkgrel=2
pkgdesc="A game in which you throw colorful bubbles and build groups to destroy the bubbles"
arch=(x86_64)
url="http://www.frozen-bubble.org"
license=(GPL2)
depends=(perl-sdl perl-ipc-system-simple perl-compress-bzip2 perl-file-which)
makedepends=(perl-file-slurp perl-locale-maketext-lexicon perl-module-build)
options=('!emptydirs')
source=(http://archive.ubuntu.com/ubuntu/pool/universe/f/frozen-bubble/frozen-bubble_${pkgver}.orig.tar.gz
        fix-buffer-size-when-formatting-current-date.patch
        frozen-bubble.desktop
        use-module-build-numeric-version.patch)
md5sums=('fe65c8b4742fcad19bd1a5ea243255c7'
         '8b189952734ca0c6e94b0959994e54d1'
         '01b10b77ba6ad856f5c199121c582272'
         '3208d2ac5338ca834fa15bc1ce3f4658')

prepare() {
  cd "$srcdir/Games-FrozenBubble-$pkgver"

  # https://bugzilla.redhat.com/show_bug.cgi?id=1541359
  patch -Np1 -i ../fix-buffer-size-when-formatting-current-date.patch

  patch -Np1 -i ../use-module-build-numeric-version.patch

  sed -e 's|-Werror||' -i inc/My/Builder.pm
}

build() {
  cd "$srcdir/Games-FrozenBubble-$pkgver"
  unset CFLAGS
  # install module in vendor directories
  perl Build.PL installdirs=vendor
  perl Build
}

check() {
  cd "$srcdir/Games-FrozenBubble-$pkgver"
  perl Build test
}

package() {
  cd "$srcdir/Games-FrozenBubble-$pkgver"
  perl Build install destdir="$pkgdir"

  install -D -m644 share/icons/frozen-bubble-icon-64x64.png "$pkgdir/usr/share/pixmaps/frozen-bubble.png"
  install -D -m644 "$srcdir/frozen-bubble.desktop" "$pkgdir/usr/share/applications/frozen-bubble.desktop"
}