blob: d982617c522a011df28332d22eb0e1cace4d6d72 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
# Maintainer: Shalygin Konstantin <k0ste@k0ste.ru>
# Contributor: Shalygin Konstantin <k0ste@k0ste.ru>
# Contributor: Evgeny Cherkashin <eugeneai@irnok.net>
pkgname='frr'
pkgver='9.0'
pkgrel='1'
pkgdesc='FRRouting (quagga fork) supports BGP4, OSPFv2, OSPFv3, ISIS, RIP, RIPng, PIM, LDP, BFD, VRRP, NHRP and EIGRP'
arch=('x86_64' 'aarch64' 'armv7h')
url="https://frrouting.org"
license=('GPL2')
depends=('libcap' 'libnl' 'readline' 'ncurses' 'perl' 'pam' 'json-c' 'net-snmp'
'rtrlib' 'libyang' 'libunwind' 'c-ares')
makedepends=('patch' 'gcc' 'net-snmp' 'bison' 'perl-xml-libxml' 'python-sphinx')
checkdepends=('python-pytest')
optdepends=('rsyslog: syslog support')
conflicts=('quagga' 'babeld' 'quagga_cumulus')
provides=('quagga' 'quagga_cumulus')
backup=("etc/${pkgname}/${pkgname}.conf"
"etc/${pkgname}/daemons.conf"
"etc/${pkgname}/vtysh.conf")
source=("https://github.com/FRRouting/${pkgname}/archive/${pkgname}-${pkgver}.tar.gz"
"${pkgname}.sysusers"
"${pkgname}.tmpfiles"
"${pkgname}_${pkgver}_Archlinux.patch"
"${pkgname}-init-functions")
sha256sums=('e818ef119ee924da0cf43d58c9eee01090f59a7b7240b989b7f529dc7d44de54'
'9371cc0522d13621c623b5da77719052bdebdceb7ffdbdc06fc32a2f07118e7e'
'6f8dd86ef9c600763faead3052908531e8dc8ef67058e6f7f8da01bf0fe4eb89'
'8635d4141f0e64eaee69eefc78afd7e9cf814f708e88d1a0e6886e1d7d9b455d'
'e6e2592a8b0b18f7f173186fb4ebf23e642b3d912179f0bb36251962ca64cd7a')
prepare() {
cd "${pkgname}-${pkgname}-${pkgver}"
patch -p1 -i "../${pkgname}_${pkgver}_Archlinux.patch"
autoreconf -fvi
./configure \
--prefix="/usr" \
--sbindir="/usr/bin" \
--sysconfdir="/etc/${pkgname}" \
--localstatedir="/run/${pkgname}" \
--with-libpam \
--enable-snmp="agentx" \
--enable-multipath=256 \
--enable-user="${pkgname}" \
--enable-group="${pkgname}" \
--enable-vty-group="${pkgname}vty" \
--enable-configfile-mask="0640" \
--enable-logfile-mask="0640" \
--enable-shell-access \
--enable-rpki \
--enable-fpm
}
build() {
cd "${pkgname}-${pkgname}-${pkgver}"
make
}
check() {
cd "${pkgname}-${pkgname}-${pkgver}"
make check
}
package() {
cd "${pkgname}-${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -Dm0444 "../frr-init-functions" "${pkgdir}/usr/bin/"
install -Dm0644 "../${pkgname}.tmpfiles" "${pkgdir}/usr/lib/tmpfiles.d/${pkgname}.conf"
install -Dm0644 "../${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
pushd "redhat"
sed -ri 's|/var/run/frr|/run/frr|g' "${pkgname}.logrotate"
install -Dm0644 "${pkgname}.logrotate" "${pkgdir}/etc/logrotate.d/${pkgname}"
install -Dm0644 "${pkgname}.pam" "${pkgdir}/etc/pam.d/${pkgname}"
popd
pushd "tools"
sed -ri 's|/usr/lib/frr/|/usr/bin/|g' "${pkgname}.service"
install -Dm0644 "${pkgname}.service" "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
popd
pushd "tools/etc"
install -Dm0644 "${pkgname}/daemons" "${pkgdir}/etc/${pkgname}/daemons.conf"
install -Dm0644 "iproute2/rt_protos.d/${pkgname}.conf" "${pkgdir}/etc/iproute2/rt_protos.d/${pkgname}.conf"
install -Dm0644 "${pkgname}/${pkgname}.conf" "${pkgdir}/etc/${pkgname}/${pkgname}.conf"
install -Dm0644 "${pkgname}/vtysh.conf" "${pkgdir}/etc/${pkgname}/vtysh.conf"
install -Dm0644 "rsyslog.d/45-${pkgname}.conf" "${pkgdir}/etc/rsyslog.d/45-${pkgname}.conf"
popd
chown -R 177:177 "${pkgdir}/etc/frr"
pushd "${pkgdir}/usr/bin"
for file in "${pkgname}" frr-reload frrcommon.sh frrinit.sh watchfrr.sh
do
sed -ri 's|/lib/lsb/init-functions|/usr/bin/frr-init-functions|g' "${file}"
done
sed -ri 's|C_PATH/daemons\"|C_PATH/daemons.conf\"|g' "frrcommon.sh"
sed -ri 's|load_old_config \"\$C_PATH/daemons.conf\"|load_old_config \"\$C_PATH/daemons\"|g' "frrcommon.sh"
popd
pushd "${pkgdir}/usr/lib/systemd/system"
sed -ri 's|frrinit.sh|frr|g' "${pkgname}.service"
popd
}
|