blob: 7bd2986251cbcc8e0dc65f33c241238b531915b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Daniel Eklöf <daniel at ekloef dot se>
CAIRO=enabled # disabled|enabled
PNG_BACKEND=libpng # none|libpng
SVG_BACKEND=librsvg # none|librsvg|nanosvg (librsvg force-enables cairo, nanosvg is bundled)
pkgname=fuzzel
pkgver=1.6.5
pkgrel=1
pkgdesc="Application launcher for wlroots based Wayland compositors"
arch=('x86_64' 'aarch64')
url=https://codeberg.org/dnkl/${pkgname}
license=(mit)
makedepends=('meson' 'ninja' 'scdoc' 'wayland-protocols' 'tllist')
depends=('libxkbcommon' 'wayland' 'pixman' 'fcft')
changelog=CHANGELOG.md
source=(${pkgname}-${pkgver}.tar.gz::${url}/archive/${pkgver}.tar.gz)
sha256sums=('b0f1af8a4b38f0cd93722d0ec35e422b5163ec3392e16467c1af8c8de94333a0')
if [[ ${PNG_BACKEND} == libpng ]]; then
depends+=( 'libpng' )
fi
if [[ ${SVG_BACKEND} == librsvg ]]; then
depends+=( 'librsvg' )
CAIRO=enabled
fi
if [[ ${CAIRO} == enabled ]]; then
depends+=( 'cairo' )
fi
build() {
cd ${pkgname}
meson \
--prefix=/usr \
--buildtype=release \
-Denable-cairo=${CAIRO} \
-Dpng-backend=${PNG_BACKEND} \
-Dsvg-backend=${SVG_BACKEND} \
. build
ninja -C build
}
package() {
cd ${pkgname}
DESTDIR="${pkgdir}/" ninja -C build install
install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
|