blob: c50dcfc308abb353601087416991dfde31064bcb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
|
# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
# Contributor: Bruno Pagani <archange@archlinux.org>
# Contributor: Filipe Laíns (FFY00) <lains@archlinux.org>
# Contributor: Frederik Schwan <freswa at archlinux dot org>
# Contributor: Mirco Tischler <mt-ml at gmx dot de>
_pkgbase=fwupd
_srcdir="${_pkgbase}-starlabs"
pkgbase=${_srcdir}-git
pkgname=(
$pkgbase
${_srcdir}-docs-git
)
pkgver=1.8.2.r2661.gea83e19
pkgrel=1
pkgdesc="Simple daemon to allow session software to update firmware (StarLabs version)"
arch=(x86_64)
url='https://github.com/fwupd/fwupd'
license=(LGPL-2.1-or-later)
depends=(
bash
bluez
curl
flashrom-starlabs
fwupd-efi
gcc-libs
glib2
glibc
gnutls
hicolor-icon-theme
json-glib
libarchive
libcbor
libdrm
libjcat
libmbim
libmm-glib
libqmi
libusb
libxmlb
passim
polkit
protobuf-c
python
shared-mime-info
sqlite
systemd-libs
tpm2-tss
xz
zlib
libgusb
)
makedepends=(
bash-completion
gi-docgen
gnu-efi-libs
gobject-introspection
meson
noto-fonts
noto-fonts-cjk
pandoc
python-cairo
python-dbus
python-dbusmock
python-gobject
python-pillow
umockdev
vala
valgrind
git
)
source=(
"${_srcdir}::git+https://github.com/StarLabsLtd/fwupd.git#branch=starlabs"
fwupd.sysusers
)
sha512sums=('SKIP'
'637203080b55eda74a659f58c853a9a723a2dad5da70915b2b0e036c6145a649468ebec700cc83975d9cb5378b9dced8b3a3b26bdbcc75ddc774837355e75deb')
pkgver() {
cd "${_srcdir}"
( set -o pipefail
git describe --tags --abbrev=7 --long 2>/dev/null | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short=7 HEAD)"
)
}
build() {
local meson_options=(
-D docs=enabled
-D efi_binary=false
-D launchd=disabled
-D supported_build=enabled
-D systemd_unit_user=fwupd
)
arch-meson ${_srcdir} build "${meson_options[@]}"
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
_pick() {
local p="$1" f d; shift
for f; do
d="$srcdir/$p/${f#$pkgdir/}"
mkdir -p "$(dirname "$d")"
mv "$f" "$d"
rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
done
}
package_fwupd-starlabs-git() {
depends+=(
libarchive.so
libcbor.so
libcurl.so
libgudev-1.0.so
libjson-glib-1.0.so
libmm-glib.so
libpassim.so
libprotobuf-c.so
libqmi-glib.so
)
optdepends=(
'python-dbus: Firmware packaging tools'
'python-gobject: Firmware packaging tools'
'udisks2: UEFI firmware upgrade support'
)
provides=(libfwupd.so ${_pkgbase})
conflicts=(${_pkgbase})
backup=(
'etc/fwupd/fwupd.conf'
'etc/fwupd/remotes.d/lvfs-testing.conf'
'etc/fwupd/remotes.d/lvfs.conf'
'etc/fwupd/remotes.d/vendor-directory.conf'
)
meson install -C build --destdir "${pkgdir}"
# Add fwupd user https://bugs.archlinux.org/task/79653
install -D -m644 fwupd.sysusers "${pkgdir}"/usr/lib/sysusers.d/fwupd.conf
# Remove the tests
rm -r "${pkgdir}"/usr/{lib,share}/installed-tests/
# Conflicts with the dbxtool package
mv "${pkgdir}"/usr/bin/{,fwupd-}dbxtool
mv "${pkgdir}"/usr/share/man/man1/{,fwupd-}dbxtool.1
# Remove msr module-load config as it is built-in
rm "${pkgdir}"/usr/lib/modules-load.d/fwupd-msr.conf
rmdir "${pkgdir}"/usr/lib/modules-load.d
_pick docs "${pkgdir}"/usr/share/doc/{,fwupd/}{libfwupdplugin,libfwupd}
}
package_fwupd-starlabs-docs-git() {
pkgdesc="Simple daemon to allow session software to update firmware - documentation"
provides=(${_pkgbase}-docs)
conflicts=(${_pkgbase}-docs)
depends=()
mv docs/* "${pkgdir}"
}
|