blob: 1823e96605c8a12b4e3e059abdb85070722094d1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
pkgname=gala-git
pkgver=0.3.0.r96.66b5d4a
pkgrel=1
pkgdesc='The Pantheon Window Manager'
arch=('x86_64')
url='https://github.com/elementary/gala'
license=('GPL3')
groups=('pantheon-unstable')
depends=('atk' 'bamf' 'cairo' 'gdk-pixbuf2' 'glib2' 'glibc' 'gnome-desktop'
'gtk3' 'json-glib' 'libdrm' 'libgee' 'libgl' 'libx11' 'libxcomposite'
'libxdamage' 'libxext' 'libxfixes' 'libxi' 'libxrandr' 'libxtst'
'mesa' 'mutter' 'pango' 'plank' 'wayland'
'libgranite.so')
makedepends=('git' 'gnome-common' 'granite-git' 'intltool' 'vala')
provides=('gala' 'libgala.so')
conflicts=('gala')
replaces=('gala-bzr')
source=('git+https://github.com/elementary/gala.git')
sha256sums=('SKIP')
pkgver() {
cd gala
git describe --tags | sed 's/-/.r/; s/-g/./'
}
build() {
cd gala
./autogen.sh \
--prefix='/usr' \
--disable-schemas-compile
make
}
package() {
cd gala
make DESTDIR="${pkgdir}" install
}
# vim: ts=2 sw=2 et:
|