blob: 8d6da962e6c624c6937b6f8f1a2e7b9ebe1b3c66 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Fernando Ortiz <nandub+arch [at] nandub.info>
# Contributor: Mark Laws <mdl [at] 60hz.org>
_pkgname=gale
pkgname=gale-git
epoch=1
pkgver=1.1.r17.ge012127
pkgrel=1
pkgdesc="A distributed, real-time instant messaging system"
arch=('i686' 'x86_64')
url="http://gale.org"
license=('GPL2')
depends=('bash' 'gc' 'openssl' 'adns')
makedepends=('git')
install="${_pkgname}.install"
source=("${_pkgname}::git+https://github.com/grawity/${_pkgname}.git")
sha1sums=('SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --tags | sed 's/^v//; s/-/.r/; s/-/./g'
}
prepare() {
cd "$srcdir/$_pkgname"
if [[ ! -f configure ]]; then
./bootstrap
fi
}
build() {
cd "$srcdir/$_pkgname"
./configure --prefix=/usr --sysconfdir=/etc
make -j1 # parallel builds seem to be broken
}
package() {
cd "$srcdir/$_pkgname"
make DESTDIR="$pkgdir" install
# install fails if sbindir = bindir
mv -f "$pkgdir/usr/sbin/gksign" "$pkgdir/usr/bin/"
rmdir "$pkgdir/usr/sbin"
}
# vim: set ts=2 sw=2 et:
|