blob: c24708011154e47940b4270ff67e9b61a9f27cb3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
|
# Maintainer: LLL2yu <lll2yu@protonmail.com>
pkgname=gallery-dl
pkgver=1.10.6
pkgrel=1
pkgdesc="Command-line program to download image-galleries and collections from several image hosting sites"
arch=('any')
url="https://github.com/mikf/gallery-dl"
license=("GPL2")
depends=('python' 'python-requests')
makedepends=('python' 'python-setuptools')
optdepends=('ffmpeg: Convert Pixiv Ugoira to WebM'
'youtube-dl: Download videos')
source=(https://github.com/mikf/${pkgname}/releases/download/v${pkgver}/gallery_dl-${pkgver}.tar.gz{,.asc})
validpgpkeys=('3E09F5908333DD83DBDCE7375680CA389D365A88') #Mike Fährmann
sha512sums=('7faeebf5f792d8cfb1fa047d75e0c1b9b64513b6b57590fe092ba75113e40a877089f911852e58fde0006693de640616e8aaf945624bb9fc90ed768e50fc9bd6'
'SKIP')
prepare(){
cd gallery_dl-$pkgver
sed -i 's|etc/bash_completion.d|share/bash-completion/completions|' setup.py
}
package() {
cd gallery_dl-$pkgver
python setup.py install -O1 --root="$pkgdir"
mv "${pkgdir}/usr/share/bash-completion/completions/gallery-dl.bash_completion" \
"${pkgdir}/usr/share/bash-completion/completions/gallery-dl"
}
|