blob: 624085ea4ff7cd045b884b7c75d1428880cc6173 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# PKGBUILD based on the official Arch gamescope PKGBUILD
# Maintainer - Sid Pranjale <sidpranjale127@protonmail.com>
# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>
# Maintainer: Bouke Sybren Haarsma <boukehaarsma23 at gmail dot com>
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
# Contributor: Samuel "scrufulufugus" Monson <smonson@irbash.net>
# Contributor: PedroHLC <root@pedrohlc.com>
_pkgname=gamescope
pkgname=${_pkgname}-git
pkgver=3.14.2.r27.gf9386a7
pkgrel=1
pkgdesc='SteamOS session compositing window manager'
arch=(x86_64)
url=https://github.com/ValveSoftware/gamescope
license=(BSD)
depends=(
gcc-libs
glibc
glm
hwdata
libavif
libcap.so
libdecor
libdisplay-info.so
libdrm
libliftoff.so
libinput
libpipewire-0.3.so
libvulkan.so
libx11
libxcb
libxcomposite
libxdamage
libxext
libxfixes
libxkbcommon
libxmu
libxrender
libxres
libxtst
libxxf86vm
seatd
sdl2
vulkan-icd-loader
wayland
xcb-util-wm
xcb-util-errors
xorg-server-xwayland
)
makedepends=(
benchmark
cmake
git
glslang
meson
ninja
vulkan-headers
wayland-protocols
)
source=('git+https://github.com/ValveSoftware/gamescope.git')
b2sums=('SKIP')
provides=("$_pkgname")
conflicts=("$_pkgname")
prepare() {
cd $_pkgname
# This really should be a pacman feature...
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
echo "Applying patch $src..."
git apply "../$src"
done
meson subprojects download
git submodule init
git -c protocol.file.allow=always submodule update
# Use Arch provided libdisplay-info, do use other subprojects as is
rm -rf subprojects/libdisplay-info
}
pkgver() {
cd $_pkgname
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
build() {
arch-meson "${_pkgname}" build \
-Dforce_fallback_for=stb \
-Dpipewire=enabled
meson compile -C build
}
package() {
meson install -C build --skip-subprojects --destdir="${pkgdir}"
cd "$srcdir/$_pkgname"
install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname/"
}
# vim: ts=2 sw=2 et:
|