blob: cb24261a456bef55764343958223817889b38f83 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>
_pkgname=gamescope
pkgname=${_pkgname}-git
pkgver=3.11.51.r3.gf863708
pkgrel=1
pkgdesc="Micro-compositor formerly known as steamcompmgr"
arch=(x86_64)
url="https://github.com/Plagman/gamescope"
license=("custom:BSD-2-Clause")
depends=(
# gamescope
"libxcomposite" "libxtst" "libxres" "sdl2" "pipewire"
# wlroots
"libdrm" "libxkbcommon" "libinput" "pixman" "xorg-xwayland" "xcb-util-renderutil" "xcb-util-wm" "xcb-util-errors" "seatd"
)
makedepends=("git" "meson" "ninja" "patch" "vulkan-headers" "glslang" "wayland-protocols" "cmake")
provides=($_pkgname "steamcompmgr")
conflicts=($_pkgname "steamcompmgr")
source=("$_pkgname::git+https://github.com/Plagman/gamescope.git"
"git+https://gitlab.freedesktop.org/wlroots/wlroots.git"
"git+https://gitlab.freedesktop.org/emersion/libliftoff.git"
"git+https://github.com/Joshua-Ashton/vkroots.git"
"git+https://github.com/nothings/stb.git")
sha512sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP')
pkgver() {
cd "$srcdir/$_pkgname"
git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "$srcdir/$_pkgname"
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
echo "Applying patch $src..."
git apply "../$src"
done
git submodule init
git config submodule.subprojects/wlroots.url "$srcdir/wlroots"
git config submodule.subprojects/libliftoff.url "$srcdir/libliftoff"
git config submodule.subprojects/vkroots.url "$srcdir/vkroots"
git -c protocol.file.allow=always submodule update
# make stb.wrap use our local clone
sed -i "s|https://github.com/nothings/stb.git|$srcdir/stb|" "subprojects/stb.wrap"
meson subprojects download
}
build() {
arch-meson "$srcdir/$_pkgname" build \
--force-fallback-for=wlroots,libliftoff,stb \
-Dpipewire=enabled \
-Dwlroots:backends=drm,libinput,x11 \
-Dwlroots:renderers=gles2,vulkan
ninja -C build
}
check() {
ninja -C build test
}
package() {
meson install -C build --skip-subprojects --destdir "$pkgdir"
cd "$srcdir/$_pkgname"
install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
install -Dm644 "README.md" "${pkgdir}/usr/share/doc/${_pkgname}/README.md"
}
|