blob: c0c246551f9cd33458826939d4af7a4f99ed8009 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: KokaKiwi <kokakiwi+aur at kokakiwi dot net>
pkgname=garage
pkgver=0.8.2
pkgrel=1
pkgdesc="Garage, an S3-compatible distributed object store for self-hosted deployments"
url="https://garagehq.deuxfleurs.fr"
license=('AGPL')
arch=('x86_64' 'i686' 'arm' 'aarch64')
depends=('gcc-libs' 'libsodium' 'zstd')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::https://git.deuxfleurs.fr/Deuxfleurs/garage/archive/v$pkgver.tar.gz")
sha256sums=('bf5bdc4250f62d4bd9b1a35d8cbdd93b39f4ceb49bf0f44d74df6137b13a8809')
b2sums=('a21f242fe2752ec0ed7376cb5c7e4560f86187991bb50d2f616a0e86f1078ff60507250215968b28b41ac46a16d4d668c1436f8ae18638eded09578f38799e5a')
export RUSTUP_TOOLCHAIN=${RUSTUP_TOOLCHAIN:-stable}
case $CARCH in
x86_64|i686|aarch64)
_target="$CARCH-unknown-linux-gnu" ;;
arm)
_target="arm-unknown-linux-gnueabi" ;;
esac
prepare() {
cd "$pkgname"
cargo fetch --locked --target $_target
}
build() {
cd "$pkgname"
CARGO_TARGET_DIR='target' \
cargo build --frozen --release --no-default-features --features 'system-libs,metrics,k2v'
}
package() {
cd "$pkgname"
install -Dm0755 -t "$pkgdir/usr/bin" \
target/release/garage
install -Dm0644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|