blob: 7a51068be0d270b0abe3b04132b63f6e91337b56 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
pkgname=garden-tools
pkgver=1.6.0
pkgrel=1
pkgdesc="Garden grows and cultivates collections of Git trees"
arch=('x86_64')
url="https://gitlab.com/garden-rs/garden"
license=('GPL-3.0-or-later')
depends=('gcc-libs')
makedepends=('cargo')
checkdepends=()
optdepends=()
provides=()
conflicts=()
replaces=()
backup=()
options=()
install=
changelog=
source=("https://gitlab.com/garden-rs/garden/-/archive/v${pkgver}/garden-v${pkgver}.tar.gz")
sha256sums=('efb51f16cd9bc76169076c5f039f9cd5f9e5522ffa81c07b29ccdcf4c8daf768')
prepare() {
cd "garden-v${pkgver}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "garden-v${pkgver}"
export CARGO_HOME="$srcdir/cargo-home"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release --all-features
# completions
target/release/garden completion bash > garden.bash
target/release/garden completion fish > garden.fish
target/release/garden completion zsh > _garden
}
package() {
cd "garden-v${pkgver}"
install -Dm755 "target/release/garden" -t "$pkgdir/usr/bin/"
# install completions
install -Dm644 garden.bash \
"$pkgdir/usr/share/bash-completion/completions/garden"
install -Dm644 garden.fish -t \
"$pkgdir/usr/share/fish/vendor_completions.d/"
install -Dm644 _garden -t \
"$pkgdir/usr/share/zsh/site-functions/"
}
|