blob: 1455b77b9cfde0059581dd67d5e16327f6fa4d7c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: acxz <akashpatel2008 at yahoo dot com>
# Contributor: Aris Synodinos <arissynod-gmail-com>
pkgname=gazebo-git
pkgver=r32546.d3584008b4
pkgrel=2
pkgdesc="A multi-robot simulator for outdoor environments. Git version."
arch=('i686' 'x86_64')
url="https://classic.gazebosim.org/"
license=('Apache')
depends=('boost' 'curl' 'freeglut' 'freeimage' 'tbb' 'libccd' 'libltdl' 'graphviz'
'libtar' 'libxml2' 'ogre-1.9' 'protobuf' 'sdformat=9' 'ignition-math=6' 'ignition-transport=8'
'ignition-cmake=2' 'ignition-common=3' 'ignition-fuel_tools=4' 'ignition-msgs=5' 'tinyxml2' 'qwt')
optdepends=('bullet: Bullet support'
'cegui: Design custom graphical interfaces'
'ffmpeg4.4: Playback movies on textured surfaces'
'gdal: Digital elevation terrains support'
'libdart: DART support'
'libspnav: space navigator joystick support'
'libusb: USB peripherals support'
'simbody: Simbody support'
'urdfdom: Load URDF files')
makedepends=('cmake' 'doxygen' 'ruby-ronn' 'git')
install="gazebo.install"
provides=('gazebo')
conflicts=('gazebo')
source=("gazebo"::"git+https://github.com/gazebosim/gazebo-classic")
sha256sums=('SKIP')
_pkgname=gazebo
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
build() {
cd "${srcdir}/${_pkgname}"
mkdir -p build && cd build
export PKG_CONFIG_PATH=/usr/lib/ffmpeg4.4/pkgconfig
cmake .. -DCMAKE_BUILD_TYPE="Release" \
-DCMAKE_INSTALL_PREFIX="/usr" \
-DCMAKE_INSTALL_LIBDIR="lib" \
-DPROTOBUF_PROTOC_EXECUTABLE="/usr/bin/protoc"
make
}
package() {
cd "${srcdir}/${_pkgname}/build"
DESTDIR="${pkgdir}" make install
}
|