summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 9c1863138a2b187c26e063e47710a1b8f64bd216 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
# Maintainer: acxz <akashpatel2008 at yahoo dot com>
# Contributor: Aris Synodinos <arissynod-gmail-com>

pkgname=gazebo-hg
pkgver=11.0.0.38902
pkgrel=1
pkgdesc="A multi-robot simulator for outdoor environments. Mercurial version."
arch=('i686' 'x86_64')
url="http://gazebosim.org/"
license=('Apache')
# See: http://www.gazebosim.org/tutorials?tut=install_from_source&cat=install
depends=('boost' 'curl' 'freeglut' 'freeimage' 'intel-tbb' 'libccd' 'libltdl'
         'libtar' 'libxml2' 'ogre=1.9' 'protobuf' 'sdformat>=9' 'ignition-math>=6'
         'ignition-transport>=8' 'ignition-common>=3' 'ignition-fuel_tools>=4'
         'ignition-msgs>=5' 'tinyxml2' 'qwt')
optdepends=('bullet: Bullet support'
            'cegui: Design custom graphical interfaces'
            'ffmpeg: Playback movies on textured surfaces'
            'gdal: Digital elevation terrains support'
            'libdart: DART support'
            'libspnav: space navigator joystick support'
            'libusb: USB peripherals support'
            'ruby-ronn: Generate manpages'
            'simbody: Simbody support'
            'urdfdom: Load URDF files')
makedepends=('cmake' 'doxygen' 'ignition-cmake>=2' 'mercurial')
install="gazebo.install"
provides=('gazebo')

_hgrepo=gazebo
_hgroot=https://bitbucket.org/osrf
_dir=${_hgrepo}

source=("${_hgrepo}"::"hg+${_hgroot}/${_hgrepo}"#branch=default)
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_dir}"

  local gazebo_major="$(sed -n 's/set (GAZEBO_MAJOR_VERSION \([0-9]\+\))/\1/p' CMakeLists.txt)"
  local gazebo_minor="$(sed -n 's/set (GAZEBO_MINOR_VERSION \([0-9]\+\))/\1/p' CMakeLists.txt)"
  local gazebo_patch="$(sed -n 's/set (GAZEBO_PATCH_VERSION \([0-9]\+\))/\1/p' CMakeLists.txt)"
  printf "%s.%s" "${gazebo_major}.${gazebo_minor}.${gazebo_patch}" "$(hg identify -n)"
}

build() {
  cd "${srcdir}/${_dir}"

  # Create build directory
  mkdir -p build && cd build

  # Run CMake
  # Note: we skip unit tests (else set to TRUE)
  cmake .. -DCMAKE_BUILD_TYPE="Release" \
           -DCMAKE_INSTALL_PREFIX="/usr" \
           -DCMAKE_INSTALL_LIBDIR="lib"

  # Compile Gazebo
  make
}

package() {
  cd "${srcdir}/${_dir}/build"

  # Install Gazebo
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: