PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68

# Maintainer: Maxwell Anselm <silverhammermba+aur@gmail.com>

pkgname=gcs
pkgver=4.0.1
pkgrel=2
pkgdesc="WYSIWYG editor for building character sheets for GURPS 4th Edition"
arch=('any')
url="http://gurpscharactersheet.com"
license=('MPL')
depends=('java-runtime=8')
makedepends=('git' 'apache-ant' 'java-environment=8' 'imagemagick')
source=(
	'git://code.trollworks.com/apple_stubs.git'
	"git://code.trollworks.com/gcs.git#tag=$pkgver"
	"git://code.trollworks.com/toolkit.git#tag=$pkgver"
	'gcs.sh'
	'gcs.desktop'
	'set_app_path_from_env.patch'
)
sha256sums=('SKIP' 'SKIP' 'SKIP'
	'a624fb16a1694c651b392cba91ff120b99ddf3dd1005b4174baca81770a8785c'
	'15f4bb0caaa0752cceba69c615e16848eba35f18b4d705caae0419a2aa0072f9'
	'f0a4f484f006da3f70fc26af15647478f6e721de113557f2cb1a93522a5f6d59'
)

prepare() {
	msg2 "Patching out hardcoded paths"
	cd "$srcdir/toolkit"
	git apply "$srcdir/set_app_path_from_env.patch"
}

build() {
	msg2 "Ensuring that Java is version 8"
	java -version 2>&1 | grep 'version "1.8' >/dev/null

	msg2 "Running ant"
	cd "$srcdir/apple_stubs"
	ant
	cd "$srcdir/toolkit"
	ant
	cd "$srcdir/gcs"
	ant
}

package() {
	msg2 "Installing files"
	# jars
	install -d "$pkgdir/usr/share/java/gcs"
	find "$srcdir" -name '*.jar' ! -name '*-src.*' -execdir install -m644 {} "$pkgdir/usr/share/java/gcs" \;

	# library
	install -d "$pkgdir/usr/share/gcs"
	cp -dr --no-preserve=ownership "$srcdir/gcs/Library" "$pkgdir/usr/share/gcs"

	# launcher
	install -Dm755 "$srcdir/gcs.sh" "$pkgdir/usr/bin/gcs"

	# .desktop
	install -d "$pkgdir/usr/share/applications"
	install -m644 "$srcdir/gcs.desktop" "$pkgdir/usr/share/applications"

	msg2 "Cleaning jar name"
	mv "$pkgdir/usr/share/java/gcs/gcs-${pkgver}.jar" "$pkgdir/usr/share/java/gcs/gcs.jar"

	msg2 "Creating icon"
	install -d "$pkgdir/usr/share/icons/hicolor/128x128/apps"
	convert "$srcdir/gcs/src/com/trollworks/gcs/app/images/app_1024.png" -resize 128 "$pkgdir/usr/share/icons/hicolor/128x128/apps/gcs.png"
}