PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=gdbm-git
pkgver=1.21.r32.gf505b9c
pkgrel=1
pkgdesc="GNU database library"
arch=('i686' 'x86_64')
url="https://www.gnu.org.ua/software/gdbm/gdbm.html"
license=('GPL3')
depends=('glibc' 'sh')
makedepends=('git' 'readline' 'rsync')
provides=('gdbm' 'libgdbm.so' 'libgdbm_compat.so')
conflicts=('gdbm')
options=('staticlibs')
source=("git+https://git.gnu.org.ua/gdbm.git")
sha256sums=('SKIP')


pkgver() {
  cd "gdbm"

  _tag=$(git tag -l --sort -v:refname | sed '/rc[0-9]*/d' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "gdbm"

  ./bootstrap
  ./configure \
    --prefix="/usr" \
    --enable-libgdbm-compat
  make
}

check() {
  cd "gdbm"

  make check
}

package() {
  cd "gdbm"

  make DESTDIR="$pkgdir" install
  install -Dm644 {AUTHORS,NEWS,NOTE-WARNING,README} -t "$pkgdir/usr/share/doc/gdbm"
}