PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Contributor: Doug Newgard <scimmia22 at outlook dot com>
# Contributor: Sagar Chalise <chalisesagar@gmail.com>

pkgname=geanypy-git
pkgver=0.01.r150.438ea69
pkgrel=1
pkgdesc="Python bindings for Geany Plugin API and plugins."
arch=('x86_64' 'i686')
url="http://codebrainz.github.com/geanypy"
license=('GPL2')
depends=('geany' 'pygtk')
makedepends=('git')
provides=("${pkgname%-*}=$pkgver")
conflicts=("${pkgname%-*}")
source=("git://github.com/codebrainz/geanypy.git")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-*}"

  local v_ver=$(awk -F , '/^AC_INIT/ {gsub(/[\[\] -]/, ""); print $2}' configure.ac)

  printf "$v_ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/${pkgname%-*}"

  sed -i '/AM_INIT_AUTOMAKE/a AM_PROG_AR' configure.ac
  sed -i 's/env python$/&2/' geany/console.py
}

build() {
  cd "$srcdir/${pkgname%-*}"

  ./autogen.sh
  ./configure --prefix=$(pkg-config --variable=prefix geany) PYTHON_VERSION=2.7

  make 
}

package() {
  cd "$srcdir/${pkgname%-*}"

  make DESTDIR="$pkgdir" install
}