blob: 6d13493ba7ee60a133ebbeef69c07a77c1bfbe97 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Ahmad Hasan Mubashshir <ahmubashshir@gmail.com>
# from: gitlab gitlab.gnome.org
# what: GNOME/gedit
pkgname=gedit-menubar
pkgver=41.alpha
pkgrel=1
pkgdesc="GNOME Text Editor (Patched to show menubar)"
url="https://wiki.gnome.org/Apps/Gedit"
arch=(x86_64)
license=(GPL)
depends=(gtksourceview4 gsettings-desktop-schemas libpeas gspell python-gobject
dconf tepl)
makedepends=(yelp-tools vala gobject-introspection git gtk-doc meson
appstream-glib desktop-file-utils libxml2)
optdepends=('gedit-plugins: Additional features')
conflicts=('gedit-code-assistance<=3.16.0+4+gd19b879-1' 'gedit')
provides=('gedit')
groups=(gnome)
source=("git+https://gitlab.gnome.org/GNOME/gedit.git#tag=$pkgver"
"git+https://gitlab.gnome.org/GNOME/libgd.git"
"menubar.patch")
sha256sums=('SKIP'
'SKIP'
'7b7bbcf115ee7a755ef039676a799bd0d2a95c36f4793e484bf296823efb2c32')
pkgver() {
cd ${pkgname%-*}
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd ${pkgname%-*}
git submodule init
git submodule set-url subprojects/libgd "$srcdir/libgd"
git submodule update
patch -p1 < "$srcdir/menubar.patch"
}
build() {
arch-meson ${pkgname%-*} build \
-D gtk_doc=true \
-D require_all_tests=true
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="$pkgdir" meson install -C build
}
|