blob: eae1becbcbbc23bddfeda871ad8383b1601e9ae0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=geforce-infinity
_app_id=net.astralvixen.geforceinfinity
pkgver=1.2.2
pkgrel=1
_nodeversion=24
_electronversion=37
pkgdesc="A next-gen application designed to enhance the GeForce NOW experience."
arch=('x86_64')
url="https://geforce-infinity.xyz"
license=('MIT')
depends=("electron${_electronversion}")
makedepends=(
'bun'
'git'
'nvm'
'python-setuptools'
'yarn'
)
source=("GeForce-Infinity-$pkgver.tar.gz::https://github.com/AstralVixen/GeForce-Infinity/archive/refs/tags/$pkgver.tar.gz"
"$pkgname.sh")
sha256sums=('40bec8d5b62dad448801edf041b3307592d207e88ba421ccd2b94c9ffd255c07'
'426e8f155c4f2273201ad33d0c0521c35bbea2259a11cb018572d6ca8b40b82d')
_ensure_local_nvm() {
# let's be sure we are starting clean
which nvm >/dev/null 2>&1 && nvm deactivate && nvm unload
export NVM_DIR="${srcdir}/.nvm"
# The init script returns 3 if version specified
# in ./.nvmrc is not (yet) installed in $NVM_DIR
# but nvm itself still gets loaded ok
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
}
prepare() {
cd "GeForce-Infinity-$pkgver"
_ensure_local_nvm
nvm install "${_nodeversion}"
sed -i "s|@ELECTRONVERSION@|${_electronversion}|" "$srcdir/$pkgname.sh"
desktop-file-edit --set-key=Exec --set-value="$pkgname" \
"com.github.astralvixen.$pkgname.desktop"
}
build() {
cd "GeForce-Infinity-$pkgver"
export npm_config_cache="$srcdir/npm_cache"
export YARN_CACHE_FOLDER="$srcdir/yarn-cache"
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
electronDist="/usr/lib/electron${_electronversion}"
electronVer="$(sed s/^v// /usr/lib/electron${_electronversion}/version)"
_ensure_local_nvm
yarn install
yarn build
yarn electron-builder --linux --x64 --dir \
$dist -c.electronDist=$electronDist -c.electronVersion=$electronVer
}
check() {
cd "GeForce-Infinity-$pkgver"
desktop-file-validate "com.github.astralvixen.$pkgname.desktop"
}
package() {
cd "GeForce-Infinity-$pkgver"
install -Dm644 builds/linux-unpacked/resources/app.asar -t \
"$pkgdir/usr/lib/$pkgname/"
cp -r builds/linux-unpacked/resources/{app.asar.unpacked,assets} -t \
"$pkgdir/usr/lib/$pkgname/"
install -Dm644 dist/assets/resources/infinitylogo.png \
"$pkgdir/usr/share/pixmaps/${_app_id}.png"
install -Dm644 "com.github.astralvixen.$pkgname.desktop" \
"$pkgdir/usr/share/applications/${_app_id}.desktop"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
}
|