PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: Martin Sandsmark <martin.sandsmark@kde.org>

pkgname=genieutils-git
pkgver=9.r603.9dd1ab9
pkgrel=1
_apiver=9
pkgdesc='A library to read/write certain data and resource files of genie engine games'
arch=('x86_64' 'i686')
url='https://github.com/sandsmark/genieutils'
license=('LGPL3')
depends=('gcc-libs' 'pcrio-git' 'zlib')
makedepends=('git' 'zstr-git')
conflicts=(genieutils)
provides=(genieutils)
source=('git+https://github.com/sandsmark/genieutils.git')
md5sums=('SKIP')

pkgver() {
    cd genieutils
    printf "${_apiver}.r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
    mkdir -p build
}

build() {
    cd build
    cmake ../genieutils \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DGUTILS_TOOLS=True

    make
}


package() {
    cd build
    make DESTDIR="$pkgdir" install
}