blob: 82993b758555bc52137a2707e8942ee7ed4a4cce (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot -de>
_pkgname=geonkick
pkgname="${_pkgname}-git"
pkgver=1.6.1.r510.96f8bd7
pkgrel=1
pkgdesc="A free software percussion synthesizer (git version)"
arch=('i386' 'x86_64')
url="http://quamplex.com/geonkick"
license=('GPL3')
groups=('pro-audio')
depends=('cairo' 'desktop-file-utils' 'hicolor-icon-theme' 'libsndfile' 'shared-mime-info')
makedepends=('cmake' 'jack' 'lv2' 'rapidjson' 'redkite' 'sord')
optdepends=('jack: for stand-alone application')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}::git+https://gitlab.com/quamplex/geonkick.git")
sha512sums=('SKIP')
pkgver() {
cd "${srcdir}/${_pkgname}"
local ver="$(grep 'geonkick VERSION' CMakeLists.txt | cut -d ' ' -f 3 | tr -d ')')"
echo "$ver.r$(git rev-list --count HEAD).$(git rev-parse --short HEAD)"
}
prepare() {
cd "${srcdir}/${_pkgname}"
# fix ignored CMAKE_INSTALL_PREFIX for redkite include directory
sed -i -e 's|/usr/local|${CMAKE_INSTALL_PREFIX}|' CMakeLists.txt
}
build() {
cd "${srcdir}/${_pkgname}"
mkdir -p build
cd build
cmake \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
..
make
}
package() {
cd "${srcdir}/${_pkgname}"
(
cd build
make DESTDIR="$pkgdir/" install
)
install -vDm 644 "data/${_pkgname}.desktop" \
-t "${pkgdir}/usr/share/applications"
install -vDm 644 examples/* \
-t "${pkgdir}/usr/share/doc/${pkgname}/examples"
install -vDm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
}
|