blob: e1116c3660e73e3c1d13133877fcea3240544992 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Caleb Maclennan <caleb@alerque.com>
pkgname=gerb-git
_pkgname=${pkgname%-git}
pkgver=0.0.1alpha.r0.g95e2946
pkgrel=1
pkgdesc='Graphical font editor (GTK + Rust) '
arch=(x86_64)
url="https://github.com/epilys/$_pkgname"
license=(GPL3)
depends=(gtk3
librsvg
python)
optdepends=('python-fonttools: Import UFOv2 or other font sources besides UFOv3'
'python-glyphslib: Import Glyphs sources'
'python-ufo2ft: Export OTF/TTF fonts')
makedepends=(cargo
git)
provides=("${pkgname%-git}=$pkgver")
conflicts=("${pkgname%-git}")
source=("git+$url.git")
sha256sums=('SKIP')
prepare() {
cd "$_pkgname"
cargo fetch --target "$CARCH-unknown-linux-gnu"
}
pkgver() {
cd "$_pkgname"
git describe --long --tags --always --abbrev=7 HEAD |
sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g;s/\+.*r/.r/;s/\.\([ab]\)/\1/'
}
build() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --release --all-features
}
check() {
cd "$_pkgname"
export RUSTUP_TOOLCHAIN=stable
cargo test --all-features
}
package() {
cd "$_pkgname"
install -Dm0755 "target/release/$_pkgname" "$pkgdir/usr/bin/$_pkgname"
}
|