blob: 6d9a9d05facdfa3c3b18c6b356b247b8b1958003 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
|
# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: Thomas Krug <t.krug@elektronenpumpe.de>
pkgname=gerbv-git
_pkgname=gerbv
pkgver=2.9.6.r1.g6b4f6ba
pkgrel=1
epoch=3
pkgdesc="An open source Gerber file (RS-274X only) viewer"
url="https://github.com/gerbv/gerbv"
license=('GPL')
arch=('i686' 'x86_64')
depends=('gtk2')
provides=('gerbv')
conflicts=('gerbv')
optdepends=('cairo: for better graphics')
makedepends=('git' 'gettext')
source=("git+$url.git")
sha256sums=('SKIP')
pkgver() {
cd $_pkgname
git describe --tags | cut -c2- | sed 's+-+.r+' | tr - .
}
prepare() {
cd $_pkgname
sed -i -e "s/m4_esyscmd(utils\/git-version-gen.sh [0-9.]*)/$pkgver/" configure.ac
}
build () {
cd $_pkgname
./autogen.sh
./configure --prefix=/usr \
--disable-update-desktop-database
make
}
package() {
cd $_pkgname
make DESTDIR="$pkgdir" install
}
|