summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6e7dfedcbeb7806f30b178c6127853a3b01824dc (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
# Maintainer: Alex3236 <me@alex3236.moe>

pkgname=gety-bin
pkgver=0.6.5
pkgrel=1
pkgdesc="The local file search engine for you and your AI agents, made by Listary team"
arch=('x86_64')
url="https://gety.ai/"
license=('LicenseRef-Gety-ToS')
depends=(
    'cairo'
    'gcc-libs'
    'gdk-pixbuf2'
    'glib2'
    'glibc'
    'gtk3'
    'libayatana-appindicator'
    'libsoup3'
    'webkit2gtk-4.1'
)
provides=('gety')
conflicts=('gety' 'gety-appimage')
options=('!strip')
source=(
    "gety-${pkgver}.deb::https://dl.gety.ai/Gety-linux-x64-${pkgver}-beta.deb"
    "gety-license.txt"
)
sha256sums=('72da381a5249bf6c83d7e634f073cf35687c68630ea22b3c0bce89e9d0660dba'
            'fe5811b6741770c6dded6256176f4a71bdf2918541a1191767484984e810172e')

package() {
    cd "$srcdir"
    rm -rf deb
    mkdir -p deb/root
    cd deb
    ar x "$srcdir/gety-${pkgver}.deb"
    tar -xzf data.tar.gz -C root

    # 0.6.2 resolves its helpers relative to the executable
    # (<exedir>/../lib/gety/), so the deb layout installs as-is:
    #   /usr/bin/gety
    #   /usr/lib/gety/{deno,aria2c,mcp-proxy,gety-reporter}
    #   /usr/lib/Gety/{lib,resources}
    # No /usr/bin pollution, hence no bwrap wrapper needed (<=0.5.7 did).
    cp -a root/usr "$pkgdir/"

    # Gety ships no license text; distribute the terms snapshot from gety.ai
    # (maintained in this repo as gety-license.txt, like google-chrome's
    # eula_text.html). Refresh it manually when upstream terms change.
    install -Dm644 "$srcdir/gety-license.txt" \
        "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}