summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 233ad96cf8b92c330f729d065e1c255a336c2bfd (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Maintainer: Gabriele Musco <emaildigabry@gmail.com>
# Upstream URL: https://gitlab.com/gabmus/gnome-feeds

pkgname=gnome-feeds-git
pkgver=0.5.r1.g5d654ae
pkgrel=1
pkgdesc='News reader for GNOME'
arch=('any')
url='https://gitlab.com/gabmus/gnome-feeds'
license=('GPL3')
depends=('gtk3' 'python' 'python-pillow' 'libhandy' 'python-listparser' 'python-feedparser' 'python-requests' 'python-lxml' 'webkit2gtk' 'python-html5lib' 'python-gobject' 'gobject-introspection')
makedepends=('git' 'meson')
provides=('gnome-feeds')
conflicts=('gnome-feeds')
source=("gfeeds::git+https://gitlab.com/gabmus/gnome-feeds")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/gfeeds"
  git describe --long --tags --always | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "$srcdir/gfeeds"
  rm -rf build
  mkdir build
  cd build
  meson --prefix /usr --buildtype release ..
  ninja
}

package() {
  cd "$srcdir/gfeeds"
  cd build
  DESTDIR="$pkgdir" ninja install
}