summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3bee770ff628cf75a8ee0289984c0912b2e511f4 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Gabriele Musco <gabmus@disroot.org>
# Upstream URL: https://gitlab.com/gabmus/gnome-feeds

pkgname=gfeeds-git
pkgver=0.16.2.r187.g91d9154
pkgrel=1
pkgdesc='News reader for GNOME'
arch=('any')
url='https://gitlab.com/gabmus/gnome-feeds'
license=('GPL3')
depends=(
  'gtk4'
  'python'
  'python-pytz'
  'python-dateutil'
  'python-pillow'
  'libadwaita-git'
  'python-requests'
  'python-lxml'
  'webkit2gtk-5.0'
  'python-html5lib'
  'python-gobject'
  'gobject-introspection'
  'python-readability-lxml'
  'python-pygments'
  'python-beautifulsoup4'
  'python-syndom-git'
  'python-humanize'
)
replaces=(gnome-feeds gnome-feeds-git)
makedepends=('git' 'meson' 'blueprint-compiler-git')
provides=('gfeeds' 'gnome-feeds')
conflicts=('gnome-feeds' 'gnome-feeds-git' 'gfeeds')
source=("gfeeds::git+https://gitlab.gnome.org/World/gfeeds")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  git describe --long --tags --always | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  arch-meson "${pkgname%-git}" build
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  meson install -C build --destdir "$pkgdir"
}