PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29

# Maintainer: Eric Engestrom <aur [at] engestrom [dot] ch>

pkgname=gfxbench
pkgver=4.0.0
pkgrel=1
pkgdesc="Unified graphics benchmark based on DXBenchmark (DirectX) and GLBenchmark (OpenGL ES)"
url='https://gfxbench.com/'
arch=('i686' 'x86_64')
license=('custom')
depends=('libpng12')
_basename="gfxbench_gl-linux-qt-${pkgver}+community"
source_i686=(  "${_basename}.sh::http://gfxbench.com/download/${_basename}_32bit.sh")
source_x86_64=("${_basename}.sh::http://gfxbench.com/download/${_basename}_64bit.sh")
md5sums_i686=(  '9eccb959962efda21f94d5bb301ece5c')
md5sums_x86_64=('9ec770568944857158b05238b8593405')

package() {
  cd "$srcdir"
  install -dm755 "$pkgdir/opt/${pkgname}/"
    sh "${_basename}.sh" \
    --skip-license \
    --prefix="$pkgdir/opt/${pkgname}/"

  install -dm755 "$pkgdir/usr/bin/"
  ln -s "/opt/${pkgname}/gfxbench_gl" "$pkgdir/usr/bin/$pkgname"

  install -dm755 "${pkgdir}/usr/share/licenses/${pkgname}/"
  awk '/END USER LICENSE AGREEMENT/,/____cpack__here_doc____/' "${_basename}.sh" | head -n-1 > "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}