PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Maintainer: c6parmak <can6parmak <AT> gmail <DOT> com>

pkgname=gfxtablet-git
pkgver=46.78d9dc0
pkgrel=1
pkgdesc="Android app to control a virtual Network Tablet on Linux"
arch=('i686' 'x86_64')
url="http://github.com/rfc2822/GfxTablet"
license=('MIT')
makedepends=('git')
source=("$pkgname"::'https://github.com/rfc2822/GfxTablet.git'
        '99-uinput.rules'
        '30-gfxtablet.conf')
md5sums=('SKIP'
         'b5d5b8e5291c08302a7a6dff8aa1ebf2'
         '18dd86149d20dfcda9dc65bc9a03d419')
install="${pkgname}.install"

pkgver() {
	cd "$pkgname"
	printf "%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
	cd "$pkgname/driver-uinput"
	make
}

package() {
	install -Dm755 "$srcdir/$pkgname/driver-uinput/networktablet" "$pkgdir/usr/bin/networktablet"
	install -Dm644 "$srcdir/99-uinput.rules" "$pkgdir/etc/udev/rules.d/99-uinput.rules"
	install -Dm644 "$srcdir/30-gfxtablet.conf" "$pkgdir/etc/X11/xorg.conf.d/30-gfxtablet.conf"
    install -Dm644 "$srcdir/$pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}