PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: surefire <surefire@cryptomile.net>

pkgname=ghetto-skype-git
pkgver=1.6.0.r0.gbe8fc90
pkgrel=1
pkgdesc="This is an electron client that uses Web Skype to better integrate with desktop environments found on Linux."
arch=("any")
url="https://github.com/stanfieldr/ghetto-skype"
license=("GPL3")
depends=('electron')
makedepends=('npm' 'asar')
conflicts=('ghetto-skype')
provides=('ghetto-skype')
options=(!emptydirs)
source=("${pkgname}::git+https://github.com/stanfieldr/ghetto-skype.git"
        'ghetto-skype.desktop'
        'ghetto-skype')
md5sums=('SKIP'
         '44aa5d2772bedba2598dbd46b0b0b4f4'
         'fd5e7e49294ee8dc3a171f882ce60a70')

pkgver() {
	cd "${pkgname}"
	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g;s/^v//'
}

prepare() {
	cd "${pkgname}"

	sed -i src/tray.js \
		-e 's/skype24.png/skype.png/' \
		-e 's/skype24-1.png/skype-1.png/' \
	;
}

build() {
	cd "${pkgname}/src"

	npm_config_nodedir=/usr/lib/electron/node npm install --production

	asar p . ../../ghetto-skype.asar
}

package() {
	install -Dm0755 -t "${pkgdir}/usr/bin"                ghetto-skype
	install -Dm0644 -t "${pkgdir}/usr/share/applications" ghetto-skype.desktop
	install -Dm0644 -t "${pkgdir}/usr/lib/ghetto-skype"   ghetto-skype.asar

	install -Dm0644 "${pkgname}/src/assets/tray/skype.png" "${pkgdir}/usr/share/pixmaps/ghetto-skype.png"
}