blob: b2327cd63cdc1d13202476183d9bacbc0d59c6fb (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Christopher Arndt <aur -at- chrisarndt -dot- de>
_pkgname=giada
pkgname="${_pkgname}-vst"
pkgver=0.15.1
pkgrel=1
pkgdesc="A looper, drum machine, sequencer, live sampler and plugin host (VST enabled)"
arch=('i686' 'x86_64')
url="http://www.giadamusic.com/"
license=('GPL3')
groups=('pro-audio')
depends=('fltk' 'jansson' 'libpulse' 'libsamplerate' 'libxpm' 'rtmidi')
makedepends=('gendesk' 'icoutils' 'steinberg-vst36')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("http://www.giadamusic.com/data/${_pkgname}-${pkgver}-src.tar.gz")
md5sums=('ba6aa45b23fb63d9442bffe5e6c42c12')
changelog='ChangeLog'
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}-src"
autoreconf -vfi
# XDG desktop file
gendesk -f -n \
--pkgname ${_pkgname} \
--pkgdesc "${pkgdesc}" \
--name Giada \
--categories "Audio;MIDI;Music;Sequencer" \
--startupnotify true
# App icon
icotool -x -i 1 -o ${_pkgname}.png src/ext/${_pkgname}.ico
}
build() {
cd "${srcdir}/${_pkgname}-${pkgver}-src"
./configure --prefix=/usr --target=linux --enable-vst
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}-src"
make DESTDIR="${pkgdir}" install
# Desktop integration
install -Dm644 ${_pkgname}.png -t "${pkgdir}/usr/share/pixmaps"
install -Dm644 ${_pkgname}.desktop -t "${pkgdir}/usr/share/applications"
# docs
install -vDm 644 {ChangeLog,README.md} \
-t "${pkgdir}/usr/share/doc/${pkgname}"
}
|