summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c86d76362f86d2eb42290740ffe623b71705977f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: Philipp Schaffrath <aur at philipp dot schaffrath dot email>

pkgname=giph-git
pkgver=r44.0a55fca
pkgrel=1
pkgdesc='gif recorder that records the desktop, a window or a selection'
url='https://github.com/phisch/giph'
license=('MIT')
arch=('any')
depends=('bash' 'ffmpeg')
optdepends=('slop: for interactive selection'
            'xdotool: for window or desktop recording'
            'zenity: for a graphical user interface')
makedepends=('git')
provides=('giph')
conflicts=('giph')
source=("$pkgname::git://github.com/phisch/giph.git")
sha256sums=('SKIP')

pkgver() {
  cd "$pkgname"
  ( set -o pipefail
    git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' ||
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
  )
}

package() {
    cd "$pkgname"
    make DESTDIR="${pkgdir}" install
    install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}