blob: 619b3b3c42b864bb540b7b2ec1f8347c6f062ba8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
# Maintainer : Kr1ss $(echo \<kr1ss+x-yandex+com\>|sed s/\+/./g\;s/\-/@/)
pkgname=git-delta
_name="${pkgname#*-}"
pkgver=0.4.0
pkgrel=1
pkgdesc='A syntax-highlighting pager for git and diff output'
arch=('i686' 'x86_64' 'arm' 'armv7h' 'armv6h' 'aarch64')
url="https://github.com/dandavison/$_name"
license=('MIT')
depends=('git')
makedepends=('rust' 'clang' 'llvm')
source=("$url/archive/$pkgver.tar.gz")
sha256sums=('cae9bda3fb1b4e1adea439bb0e834d703d5925f0ace44eafa2d1b1293ae79209')
prepare() {
# Assist chroot builds with a persistent cargo cache (hat tip @ccorn for this patch)
if [ -d "$startdir/.cargo" ]; then
export CARGO_HOME="${CARGO_HOME:-$startdir/.cargo}"
else
msg2 "NOTE : If you're building in a (clean) chroot and want a persistant
cargo cache folder specific for this package, you can create
an empty '.cargo' directory next to the 'PKGBUILD'. This will
be recognized and used as CARGO_HOME (except when CARGO_HOME is
already set)."
fi
}
build() {
cd "$_name-$pkgver"
cargo build --release --locked
}
check() {
cd "$_name-$pkgver"
cargo test --locked
}
package() {
cd "$_name-$pkgver"
install -Dm755 "target/release/$_name" -t"$pkgdir/usr/bin/"
install -Dm644 README.md -t"$pkgdir/usr/share/doc/$_name/"
cp -a --no-preserve=ownership performance "$pkgdir/usr/share/doc/$_name/"
install -Dm644 LICENSE -t"$pkgdir/usr/share/licenses/$_name/"
install -Dm644 completion/completion.bash "$pkgdir/usr/share/bash-completion/completions/$_name"
install -Dm644 completion/completion.zsh "$pkgdir/usr/share/zsh/site-functions/_$_name"
}
# vim: ts=2 sw=2 et ft=PKGBUILD:
|