summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 89373751f1c9db651b42e90995bd432f6f6ed690 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: matmoser@wu.ac.at

pkgname=git-fat-git
pkgver=r84.d5b388c
pkgrel=1
pkgdesc="Simple way to handle fat files without committing them to git"
arch=('any')
url="https://github.com/jedbrown/git-fat"
license=('BSD')
depends=('git' 'rsync' 'python2')
source=("git+https://github.com/jedbrown/git-fat.git")
md5sums=('SKIP')

pkgver() {
  cd ${pkgname%-*}

  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  # fix shebang
  sed -i '1s|env python$|&2|g' ${pkgname%-*}/git-fat
}

package() {
  cd ${pkgname%-*}

  install -Dm0755 git-fat "$pkgdir"/usr/bin/git-fat
  install -Dm0644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  install -Dm0644 README.md "$pkgdir"/usr/share/doc/$pkgname/README.md
}