blob: 42f15ad6d07e7e29a03400ec8a6b5fdfb02d7375 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
|
# Maintainer: Ilaï Deutel
pkgname='git-machete'
pkgver=2.13.5
pkgrel=1
pkgdesc="Probably the sharpest git repository organizer & rebase/merge workflow automation tool you've ever seen"
arch=('any')
url='https://github.com/VirtusLab/git-machete'
license=('MIT')
depends=('git' 'python')
makedepends=('python-setuptools')
checkdepends=('python-six')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/VirtusLab/$pkgname/archive/v$pkgver.tar.gz")
sha256sums=('47e559b83cbdda1b2ccd1c228adcb2a6dbeb2b69d9f9b888552983166be0a08f')
build() {
cd "$srcdir/$pkgname-${pkgver}"
python setup.py build
}
check() {
cd "$srcdir/$pkgname-${pkgver}"
python -m unittest
}
package() {
cd "$srcdir/$pkgname-${pkgver}"
# Install the package
python setup.py install --root="$pkgdir/" --optimize=1 --skip-build
# Install bash and zsh completions
install -Dm644 "completion/git-machete.completion.bash" "$pkgdir/usr/share/bash-completion/completions/git-machete"
install -Dm644 "completion/git-machete.completion.zsh" "$pkgdir/usr/share/zsh/site-functions/_git-machete"
# Install the license
install -Dm 644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|