blob: 9048db7a801048a703b895981ddbd7b386c5aec2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
# Maintainer: orhun <orhunparmaksiz@gmail.com>
# https://github.com/orhun/pkgbuilds
pkgname=git-metrics
pkgver=0.2.6
pkgrel=1
pkgdesc="A git extension to be able to track metrics about your project"
arch=('x86_64')
url="https://github.com/jdrouet/git-metrics"
license=('MIT')
depends=('gcc-libs' 'git' 'openssl' 'zlib')
makedepends=('cargo')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha256sums=('d8e25146d627bd55bc2780fa0f298943b13dd148be12cd5fdfef5aab3e744624')
options=('!lto')
prepare() {
cd "$pkgname-$pkgver"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --frozen
}
# check() {
# cd "$pkgname-$pkgver"
# cargo test --frozen
# }
package() {
cd "$pkgname-$pkgver"
install -Dm 755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm 644 readme.md -t "$pkgdir/usr/share/doc/$pkgname"
install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}
|