blob: 56af1a225a5242552ac48a6e586c4a4212eef9e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Arti Zirk <arti.zirk@gmail.com>
# Contributor: James An <james@jamesan.ca>
pkgname=git-subrepo-git
_pkgname=${pkgname%-git}
pkgver=0.4.3.r1.g2f68596
pkgrel=2
pkgdesc='Git Submodule Alternative'
arch=('any')
url="https://github.com/ingydotnet/$_pkgname"
license=('GPL')
provides=("$_pkgname=$pkgver")
conflicts=("$_pkgname")
source=("$_pkgname"::"git+$url.git")
md5sums=('SKIP')
depends=(git)
pkgver() {
cd "$_pkgname"
(
set -o pipefail
git describe --long --tag | sed -r 's/([^-]*-g)/r\1/;s/-/./g' ||
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
)
}
build() {
cd "$_pkgname"
make compgen
}
check() {
cd "$_pkgname"
make test
}
package() {
cd "$_pkgname"
make DESTDIR="$pkgdir" PREFIX=/usr install
install -d -m 0755 "$pkgdir"/usr/share/bash-completion/completions
install -C -m 0644 share/completion.bash "$pkgdir"/usr/share/bash-completion/completions/git-subrepo
install -d -m 0755 "$pkgdir"/usr/share/zsh/site-functions
install -C -m 0644 share/zsh-completion/_git-subrepo "$pkgdir"/usr/share/zsh/site-functions/_git-subrepo
}
|