PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Maintainer: Caleb Maclennan <caleb@alerque.com>

pkgname=git-withme
pkgver=26.3.0
pkgrel=1
pkgdesc='Encrypted, peer-to-peer Git for two+ people'
arch=(any)
url="https://pypi.org/project/$pkgname"
license=(MIT)
_pydeps=(click
         humanize
         rich)
depends=(fowl
         magic-wormhole
         python
         "${_pydeps[@]/#/python-}")
makedepends=(python-{build,installer,wheel}
             python-hatchling)
checkdepends=(python-pytest)
_archive="${pkgname/-/_}-$pkgver"
source=("https://files.pythonhosted.org/packages/source/${pkgname::1}/$pkgname/$_archive.tar.gz")
sha256sums=('face0ee0adb9a87f6af096c23a3476a4bbda49e32ac41d406b702951d7b31425')

build() {
	cd "$_archive"
	python -m build -wn
}

check() {
	cd "$_archive"
	pytest
}

package() {
	cd "$_archive"
	python -m installer -d "$pkgdir" dist/*.whl
	install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
	install -Dm0644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}