blob: 4c7d66e856b20c398ae160ff432b960493e83bfd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
# Maintainer: zxp19821005 <zxp19821005 at 163 dot com>
# Contributor: PolpOnline <aur at t0mmy dot anonaddy dot com>
pkgname=gitify
_pkgname=Gitify
pkgver=5.5.0
_electronversion=30
_nodeversion=20
pkgrel=1
pkgdesc="GitHub notifications on your menu bar."
arch=('any')
url='https://www.gitify.io/'
_ghurl="https://github.com/gitify-app/gitify"
license=('MIT')
depends=(
"electron${_electronversion}"
)
makedepends=(
'gendesk'
'nvm'
'npm'
'pnpm'
'icoutils'
'curl'
)
source=(
"${pkgname}-${pkgver}.tar.gz::${_ghurl}/archive/refs/tags/v${pkgver}.tar.gz"
"${pkgname}.sh"
)
sha256sums=('7599ac392f697dcf2c7dd7ce5f3180b194f98d6926fe17da16877a9e78d10e57'
'2b2e8aeed33fd71c521e49fd54fb2fa81218d16aef8bccb88d77909055ab8051')
_ensure_local_nvm() {
export NVM_DIR="${srcdir}/.nvm"
source /usr/share/nvm/init-nvm.sh || [[ $? != 1 ]]
nvm install "${_nodeversion}"
nvm use "${_nodeversion}"
}
build() {
sed -e "s|@electronversion@|${_electronversion}|" \
-e "s|@appname@|${pkgname}|g" \
-e "s|@runname@|app.asar|g" \
-e "s|@cfgdirname@|${pkgname}|g" \
-e "s|@options@|env ELECTRON_OZONE_PLATFORM_HINT=auto|g" \
-i "${srcdir}/${pkgname}.sh"
gendesk -f -n -q --categories="Development" --name="${_pkgname}" --exec="${pkgname} %U"
cd "${srcdir}/${pkgname}-${pkgver}"
export npm_config_build_from_source=true
export ELECTRON_SKIP_BINARY_DOWNLOAD=1
#export SYSTEM_ELECTRON_VERSION="$(electron${_electronversion} -v | sed 's/v//g')"
#export npm_config_target="${SYSTEM_ELECTRON_VERSION}"
#export ELECTRONVERSION="${_electronversion}"
HOME="${srcdir}/.electron-gyp"
pnpm config set store-dir "${srcdir}/.pnpm_store"
pnpm config set cache-dir "${srcdir}/.pnpm_cache"
pnpm config set link-workspace-packages true
if [ `curl -s ipinfo.io/country | grep CN | wc -l ` -ge 1 ];then
export npm_config_registry=https://registry.npmmirror.com
export npm_config_disturl=https://registry.npmmirror.com/-/binary/node/
export npm_config_electron_mirror=https://registry.npmmirror.com/-/binary/electron/
export npm_config_electron_builder_binaries_mirror=https://registry.npmmirror.com/-/binary/electron-builder-binaries/
else
echo "Your network is OK."
fi
sed 's|"AppImage", "deb", "rpm", "snap"|"dir"|g;/packageManager/d' -i package.json
icotool -x assets/images/app-icon.ico -o assets/images/app-icon.png
pnpm install
pnpm run build
pnpm run make:linux
}
package() {
install -Dm755 "${srcdir}/${pkgname}.sh" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/dist/linux-"*/resources/app.asar -t "${pkgdir}/usr/lib/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}.desktop" -t "${pkgdir}/usr/share/applications"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/assets/images/app-icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
install -Dm644 "${srcdir}/${pkgname}-${pkgver}/LICENSE" -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|