blob: d1604654cddb3b7697174f637557bda72ed47528 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Anas Elgarhy <anas.elgarhy.dev@gmail.com>
pkgname=gitpane-git
_pkgname=gitpane
pkgver=0.5.3.r1.gb8b5929
pkgrel=1
pkgdesc='Multi-repo Git workspace dashboard for the terminal'
arch=('x86_64' 'aarch64' 'riscv64')
url='https://github.com/affromero/gitpane'
license=('MIT')
depends=('git')
makedepends=('cargo' 'patch' 'git')
options=(!lto)
provides=('gitpane')
conflicts=('gitpane' 'gitpane-bin')
source=("$_pkgname-main::git+$url.git#branch=main"
'disable-self-updates.patch')
sha256sums=('SKIP'
'3de1d97cf8e0f44c381978a5e65de656710d75f2e64595fb295edfdb2ef9cfb4')
pkgver() {
cd "${_pkgname}-main"
git describe --long --abbrev=7 --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd "${_pkgname}-main"
patch -p1 < ../disable-self-updates.patch
cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
}
build() {
cd "${_pkgname}-main"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
package() {
cd "${_pkgname}-main"
install -Dm0755 target/release/gitpane "$pkgdir/usr/bin/gitpane"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname/" README.md
}
# vim: ts=4 sw=4 et:
|