blob: 80123128d8a219f269af115c055766ebd21f91b9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
# Maintainer: Christian Muehlhaeuser <muesli at gmail dot com>
pkgname=gitty
pkgver=0.7.0
pkgrel=1
pkgdesc="A smart little CLI helper for git projects"
arch=('x86_64' 'i686' 'armv6h' 'armv7h' 'aarch64')
url="https://github.com/muesli/${pkgname}"
license=('MIT')
makedepends=('git' 'go')
source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('cea3f7fa92653abd18ce951f24c64321edab8d8da9340f764c25cbfe8eba36ef')
build() {
local commit
local extraflags
commit=$(zcat ${pkgname}-${pkgver}.tar.gz | git get-tar-commit-id)
extraflags="-X main.Version=${pkgver} -X main.CommitSHA=${commit}"
export CGO_CPPFLAGS="${CPPFLAGS}"
export CGO_CFLAGS="${CFLAGS}"
export CGO_CXXFLAGS="${CXXFLAGS}"
export CGO_LDFLAGS="${LDFLAGS}"
cd "$pkgname-$pkgver"
go build \
-trimpath \
-buildmode=pie \
-mod=readonly \
-modcacherw \
-ldflags "${extraflags} -extldflags \"${LDFLAGS}\"" \
-o "$pkgname" .
}
package() {
cd "$pkgname-$pkgver"
install -Dm755 "$pkgname" "$pkgdir/usr/bin/$pkgname"
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
# vim:set ts=4 sw=4 et:
|