PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82

# Maintainer: Fabio 'Lolix' Loli <lolix@disroot.org>
# Contributor: Tim Schumacher <timschumi@gmx.de>
# Contributor: KillWolfVlad <github.com/KillWolfVlad>
# Contributor: WaveHack <email@wavehack.net>
# Contributor: Whovian9369 <Whovian9369@gmail.com>

pkgname=gittyup-git
pkgver=r534.4313005
pkgrel=1
pkgdesc="Graphical Git client (GitAhead fork)"
url="https://github.com/Murmele/Gittyup"
arch=(x86_64)
license=(MIT)
depends=(qt5-base cmark libssh2 libsecret)
makedepends=(git cmake ninja qt5-tools qt5-translations libgnome-keyring)
optdepends=('libgnome-keyring: for GNOME Keyring for auth credentials'
            'qt5-translations: translations '
            'git-lfs: git-lfs support')
provides=(gittyup)
conflicts=(gittyup)
source=("${pkgname%-git}::git+https://github.com/Murmele/Gittyup.git"
        "git+https://github.com/stinb/libgit2.git"
        "git+https://github.com/git/git.git"
        "git+https://github.com/libssh2/libssh2.git"
        "git+https://github.com/hunspell/hunspell.git"
        'gittyup.desktop')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'a07943687afee5f3664219373b60ae54eaa207414646181df107893407119462')

pkgver() {
  cd "${srcdir}/${pkgname%-git}"
  #git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "${srcdir}/${pkgname%-git}"

  git submodule init
  git config 'submodule.dep/libgit2/libgit2.url' "${srcdir}/libgit2"
  git config 'submodule.dep/git/git.url' "${srcdir}/git"
  git config 'submodule.dep/libssh2/libssh2.url' "${srcdir}/libssh2"
  git config 'submodule.dep/hunspell/hunspell.url' "${srcdir}/hunspell"
  git -c submodule.dep/openssl/openssl.update=none -c submodule.dep/cmark/cmark.update=none submodule update

  install -d build
}

build() {
  cd "${srcdir}/${pkgname%-git}/build"
  cmake -G Ninja .. -Wno-dev \
    -DCMAKE_BUILD_TYPE=None \
    -DCMAKE_INSTALL_PREFIX=/usr/lib/gittyup \
    -DCMAKE_INSTALL_MANDIR=/usr/share/man \
    -DENABLE_REPRODUCIBLE_BUILDS=ON \
    -DBUILD_SHARED_LIBS=OFF

  ninja
}

package() {
  cd "${srcdir}/${pkgname%-git}"
  DESTDIR="${pkgdir}" ninja -C build install

  rm -rf "${pkgdir}/usr/lib/gittyup/"*.so.*
  install -d "${pkgdir}/usr/bin"
  ln -s /usr/lib/gittyup/Gittyup "${pkgdir}/usr/bin/gittyup"

  install -Dm644 LICENSE.md "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
  install -Dm644 ../gittyup.desktop "${pkgdir}/usr/share/applications/gittyup.desktop"

  install -Dm644 rsrc/Gittyup.iconset/gittyup_logo.svg "${pkgdir}/usr/share/icons/hicolor/scalable/apps/gittyup.svg"
  for s in 16x16 32x32 64x64 128x128 256x256 512x512; do
    install -Dm0644 "rsrc/Gittyup.iconset/icon_$s.png" "icons/hicolor/$s/apps/$pkgname.png"
  done

  rm -rf "${pkgdir}/usr/share/man" # libssh2 man pages
}