blob: a52b08f89ac2e87b94c8d386e83a25c761306b66 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: Pellegrino Prevete <pellegrinoprevete@gmail.com>
# Contributor: Kevin Majewski <kevin.majewski02@gmail.com>
# Contributor: VitalyR <vitalyankh@gmail.com>
# shellcheck disable=SC2034
_pkgname="gjs"
pkgname="${_pkgname}-git"
pkgver=1.73.2+23+ge78966e1
pkgrel=1
epoch=2
pkgdesc="Javascript Bindings for GNOME"
url="https://gitlab.gnome.org/GNOME/${_pkgname}/blob/master/doc/Home.md"
arch=('x86_64' 'i686' 'pentium4')
license=(GPL)
depends=('cairo' 'gobject-introspection-runtime' 'js102' 'dconf')
makedepends=('gobject-introspection' 'git' 'autoconf-archive' 'sysprof' 'meson')
checkdepends=('valgrind' 'xorg-server-xvfb')
provides=("${_pkgname}=${pkgver}")
conflicts=("${_pkgname}")
source=("git+https://gitlab.gnome.org/GNOME/${_pkgname}.git/")
sha256sums=('SKIP')
pkgver() {
cd "${_pkgname}" || exit
git describe --tags | sed 's/-/+/g'
}
build() {
arch-meson "${_pkgname}" build
ninja -C build
}
check() {
meson test -C build --print-errorlogs
}
# shellcheck disable=SC2154
package() {
DESTDIR="${pkgdir}" meson install -C build
}
|