PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Robin Broda <robin at broda dot me>

_pkgname=glava
pkgname=${_pkgname}-git
pkgver=r329.3cc5e22
pkgrel=2
pkgdesc='OpenGL audio spectrum visualizer'
arch=('x86_64')
url='https://github.com/wacossusca34/glava'
license=('GPL3')
depends=('x-server' 'pulseaudio' 'libxext' 'libxcomposite' 'libxrender')
makedepends=('git' 'meson' 'obs-studio')
optdepends=('obs-studio: OBS integration')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=('git+https://github.com/wacossusca34/glava'
        'git+https://github.com/Dav1dde/glad')
md5sums=('SKIP'
         'SKIP')

pkgver() {
	cd "${_pkgname}"
	printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
	cd "${_pkgname}"

	git submodule init
	git config submodule.glad.url "${srcdir}/glad"
	git submodule update
}

build() {
	cd "${_pkgname}"

	arch-meson build --prefix /usr
	ninja -C build
}

package() {
	cd "${_pkgname}"

	DESTDIR="${pkgdir}/" ninja -C build install
}