blob: 6594d3502fa69a5f6794e3906253bb9872bf3371 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Maintainer: Solomon Choina <shlomochoina@gmail.com>
pkgbase=glib2-selinux
pkgname=(glib2-selinux glib2-selinux-docs)
pkgver=2.66.4
pkgrel=6
pkgdesc="Low level core library"
url="https://wiki.gnome.org/Projects/GLib"
license=(LGPL)
arch=(x86_64)
depends=(pcre libffi util-linux-libs zlib)
makedepends=(gettext gtk-doc shared-mime-info python libelf git util-linux
meson dbus sysprof libselinux)
_commit=bacbec652d356895ec493f3de2f2f6f4c7dafde0 # tags/2.66.4^0
source=("git+https://gitlab.gnome.org/GNOME/glib.git#commit=$_commit"
noisy-glib-compile-schemas.diff
glib-compile-schemas.hook gio-querymodules.{hook,script})
sha256sums=('SKIP'
'81a4df0b638730cffb7fa263c04841f7ca6b9c9578ee5045db6f30ff0c3fc531'
'64ae5597dda3cc160fc74be038dbe6267d41b525c0c35da9125fbf0de27f9b25'
'2a9f9b8235f48e3b7d0f6cfcbc76cd2116c45f28692cac4bd61074c495bd5eb7'
'92d08db5aa30bda276bc3d718e7ff9dd01dc40dcab45b359182dcc290054e24e')
pkgver() {
cd glib
git describe --tags | sed 's/-/+/g'
}
prepare() {
cd glib
# Suppress noise from glib-compile-schemas.hook
git apply -3 ../noisy-glib-compile-schemas.diff
}
build() {
CFLAGS+=" -DG_DISABLE_CAST_CHECKS"
arch-meson glib build \
-D selinux=enabled \
-D man=true \
-D gtk_doc=true
meson compile -C build
}
package_glib2-selinux() {
depends+=(libmount.so)
provides+=(libgio-2.0.so libglib-2.0.so libgmodule-2.0.so libgobject-2.0.so
libgthread-2.0.so glib2)
conflicts=(glib2=$pkgver)
optdepends=('python: gdbus-codegen, glib-genmarshal, glib-mkenums, gtester-report'
'libelf: gresource inspection tool'
'selinux: selinux support')
DESTDIR="$pkgdir" meson install -C build
install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
install -D gio-querymodules.script "$pkgdir/usr/share/libalpm/scripts/gio-querymodules"
# Avoid a dep on sysprof
sed -i 's/, sysprof-capture-4//' "$pkgdir"/usr/lib/pkgconfig/*.pc
export PYTHONHASHSEED=0
python -m compileall -d /usr/share/glib-2.0/codegen \
"$pkgdir/usr/share/glib-2.0/codegen"
python -O -m compileall -d /usr/share/glib-2.0/codegen \
"$pkgdir/usr/share/glib-2.0/codegen"
# Split docs
mkdir -p docs/usr/share
mv {"$pkgdir",docs}/usr/share/gtk-doc
}
package_glib2-selinux-docs() {
pkgdesc="Documentation for GLib"
# conflicts=(glib2-docs)
provides=(glib2-docs)
license+=(custom)
mv -t "$pkgdir" docs/*
install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 glib/docs/reference/COPYING
}
# vim:set sw=2 et:
|