blob: 78a74d8efd69db53843ccc02b2ce00c84ceaf296 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Maintainer: Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
pkgname=glimpse-editor-git
pkgver=0.1.0.r95.gf1cd9dc9cd
pkgrel=1
pkgdesc="Fork of the GNU Image Manipulation Program"
arch=(i686 x86_64)
url="https://glimpse-editor.org/"
license=(GPL3 LGPL)
depends=(gegl libmypaint gtk2 pygtk openexr
poppler-glib poppler-data mypaint-brushes1
)
makedepends=(git intltool libxslt gtk-doc libxslt
ghostscript libxpm libheif libwebp libmng libwmf iso-codes aalib
appstream-glib xdg-utils
)
optdepends=('gutenprint: for sophisticated printing only as glimpse has built-in cups print support'
'alsa-lib: for MIDI event controller module'
'ghostscript: for postscript support'
'libxpm: XPM support'
'libheif: HEIF support'
'libwebp: WebP support'
'libmng: MNG support'
'iso-codes: Language support'
'xdg-utils: email plugin'
'aalib: ASCII art support'
)
provides=(glimpse-editor gimp)
conflicts=(glimpse-editor gimp)
source=("git+https://github.com/glimpse-editor/Glimpse")
sha512sums=('SKIP')
pkgver() {
cd Glimpse
git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
}
prepare() {
cd Glimpse
_mypaintver=$(echo /usr/lib/libmypaint-*.so | grep -o -E '\-[0-9]+(\.[0-9]+)*' | head -1)
sed -i "s|\\(libmypaint\\)\\( >= libmypaint_required_version\\)|\\1${_mypaintver}\\2|g" configure.ac
./autogen.sh
}
build() {
cd Glimpse
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libexecdir=/usr/bin \
--enable-mp \
--enable-gimp-console \
--enable-gtk-doc \
--disable-python \
--with-bug-report-url=https://aur.archlinux.org/packages/glimpse-editor-git/ \
--with-openexr
make
}
package() {
cd Glimpse
make DESTDIR="$pkgdir" install
ln -s gimptool-2.0 "$pkgdir"/usr/bin/gimptool
install -Dm 644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}"/COPYING
install -Dm 644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}"/LICENSE
}
|