blob: cb38d6f4ef08d73ce29ef1903633e3f705a93101 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Peter Vasil <mail@petervasil.net>
# Contributor: Lucas De Marchi <lucas.de.marchi@gmail.com>
# Contributor: Matthias Meulien orontee@gmail.com
pkgname=global
pkgver=6.5.1
pkgrel=1
pkgdesc="A source code tag system"
arch=('i686' 'x86_64')
url="http://www.gnu.org/software/global/"
license=('GPL')
depends=('libltdl' 'bash' 'perl')
optdepends=('idutils' 'ctags' 'python2-pygments')
options=(!emptydirs !libtool)
install=global.install
source=(http://tamacom.com/global/${pkgname}-${pkgver}.tar.gz)
md5sums=('5009690a3a6288127460d5d461d4a153')
sha256sums=('0e9d5227d400e8cb2ffa1732d98b8735d58d4bf8476c2845365770fdd5b264f8')
prepare() {
cd "${srcdir}/${pkgname}-${pkgver}"
sed -i 's/\.la/.so/g' gtags.conf.in
}
build() {
cd "${srcdir}/${pkgname}-${pkgver}"
autoreconf -fi
PYTHON=/usr/bin/python2 ./configure --prefix=/usr --with-exuberant-ctags=/usr/bin/ctags
make
}
check() {
cd "${srcdir}/${pkgname}-${pkgver}"
make -k check
}
package() {
cd "${srcdir}/${pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
install -d "${pkgdir}/usr/share/emacs/site-lisp"
ln -s ../../gtags/gtags.el "${pkgdir}/usr/share/emacs/site-lisp/gtags.el"
}
|