PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: Nicolas Stalder <n+archlinux@stalder.io>
pkgname=globalplatformpro
pkgver=20.08.12
pkgrel=5
pkgdesc="Manage applets and keys on JavaCard-s like a pro"
arch=('any')
url="https://github.com/martinpaljak/GlobalPlatformPro"
license=('LGPL3')
depends=('java-runtime-headless' 'pcsclite')
makedepends=('git' 'java-environment' 'maven' 'which')
source=(
  "$pkgname::git+https://github.com/martinpaljak/GlobalPlatformPro.git#tag=v${pkgver}"
  'gpp'
)
sha256sums=(
  'SKIP'
  'a8769c37ac54b3e98645f509b011a290d7e914937de0158cc8f2a8fcef0e255e'
)

prepare() {
	cd $pkgname
	# otherwise git complains about nested tags
	git config user.email makepkg@example.com
	git config user.name "makepkg"
	git tag -f -a v${pkgver} -m "v${pkgver}" v${pkgver}^{}
}

build() {
  cd $pkgname
  mvn package
}

package() {
  # Install the executables
  install -d "$pkgdir"/usr/bin/
  install -m 755 gpp "$pkgdir"/usr/bin/
  cd $pkgname
  install -d "$pkgdir"/usr/share/java/globalplatformpro/
  install -m 644 tool/target/gp.jar "$pkgdir"/usr/share/java/globalplatformpro/
}