blob: fbd22ebd47111b6e2b2d6cb20d415e79bffc1db5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>
pkgname=glpk-git
pkgver=5.0.r242.g4e03800
pkgrel=1
pkgdesc="GNU Linear Programming Kit: solve LP, MIP and other problems"
arch=('i686' 'x86_64')
url="https://www.gnu.org/software/glpk/"
license=('GPL')
depends=('glibc' 'gmp')
makedepends=('git')
provides=("glpk=$pkgver")
conflicts=('glpk')
options=('staticlibs')
source=("git+https://salsa.debian.org/science-team/glpk.git")
sha256sums=('SKIP')
pkgver() {
cd "glpk"
_tag=$(git tag -l --sort -v:refname | grep -E '^upstream/[0-9\.]+$' | head -n1)
_rev=$(git rev-list --count $_tag..HEAD)
_hash=$(git rev-parse --short HEAD)
printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's|^upstream/||'
}
build() {
cd "glpk"
./autogen.sh
./configure \
--prefix="/usr" \
--with-gmp
make
}
check() {
cd "glpk"
make check
}
package() {
cd "glpk"
make DESTDIR="$pkgdir" install
install -Dm644 doc/{glpk,gmpl}.pdf -t "$pkgdir/usr/share/doc/glpk"
}
|